Financial Modeling: Investment Property Model

You may want to follow along by downloading the 'Investment Property Model' in the related documents box.

Before we jump into building a financial model, we should ask ourselves what drives the business that we are exploring. The answer will have significant implications for how we construct the model.

For example, a financial institution such as a bank is driven by its assets (investments, loans, mortgages, etc.), therefore we would probably be better off forecasting the growth of the company’s balance sheet. A retail store, on the other hand, is driven by the sales of its products. Therefore, we should focus on forecasting revenues and the income statement.

Who Will Use It?

Other questions to ask are who will be using this model and what will they be using it for? A company may have a new product for which they need to calculate an optimal price. Or an investor may want to map out a project to see what kind of investment return he or she can expect.

Depending on these scenarios, the end result of what the model will calculate may be very different. Unless you know exactly what decision the user of your model needs to make, you may find yourself starting over several times until you find an approach that uses the right inputs to find the appropriate outputs.

On to Real Estate

In our scenario, we want to find out what kind of financial return we can expect from an investment property given certain information about the investment. This information would include variables such as the purchase price, rate of appreciation, the price at which we can rent it out, the financing terms available fore the property, etc.

Our return on this investment will be driven by two primary factors: our rental income and the appreciation of the property value. Therefore, we should begin by forecasting rental income and the appreciation of the property in consideration.

Once we have built out that portion of the model, we can use the information we have calculated to figure out how we will finance the purchase of the property and what financial expenses we can expect to incur as a result.

The next section we can tackle is forecasting the property management expenses. We will need to use the property value that we forecasted in order to be able to calculate property taxes, so it is important that we build the model in a certain order.

Once we have these projections in place, we can begin to piece together the income statement and the balance sheet. As we put these in place, we may spot items that we haven’t yet calculated and we may have to go back and add them in the appropriate places.

Finally, we can use these financials to project the cash flow to the investor and calculate our return on investment.

Laying Out the Model

Since we are about to build a somewhat complicated model, we should think about how we want to lay it out so we keep our workspace clean. In Excel, one of the best ways to organize financial models is to separate certain sections of the model on different worksheets.

By putting calculations and projections that are closely related in the same worksheet and separating other calculations that are more relevant to other sections of the model on separate tabs (worksheets), we keep our model organized.

We can give each tab a name that describes the information contained in it. This way, other users of the model can better understand where data is calculated in the model and how it flows.

In our investment property model, let’s use four tabs: property, financing, expenses and financials. Property, financing and expenses will be the tabs on which we input assumption and make projections for our model. The financials tab will be our results page where we will display the output of our model in a way that’s easily understood (in the form of financial statements).

Forecasting Revenues

First Things first, let’s start with the property tab by renaming the tab “Property” and adding this title in cell A1 of the worksheet. By taking care of some of these formatting issuing on the front end, we’ll have an easier time keeping the model clean.

Next, let’s set up our assumptions box. A few rows below the title, type “Assumptions” and make a vertical list of the following inputs:

Purchase Price
Initial Monthly Rent
Occupancy Rate
Annual Appreciation
Annual Rent Increase
Broker Fee
Investment Period

In the cells to the right of each input label, we’ll set up an input field by adding a realistic placeholder for each value. We will format each of these values to be blue in color. This is a common modeling convention to indicate that these are input values. This formatting will make it easier for us and others to understand how the model flows. Here are some corresponding values to start with:

$250,000.00
$1,550.00
95.00%
3.50%
1.00%
6.00%
4 years

The purchase price will be the price we expect to pay for a particular property. The initial monthly rent will be the price for which we expect to rent out the property. The occupancy rate will measure how well we keep the property rented out (95% occupancy will mean that there will only be about 18 days that the property will go un-rented between tenants each year).

Annual appreciation will determine the rate that the value of our property increases (or decreases) each year. Annual rent increase will determine how much we will increase the rent each year. The broker fee measures what percentage of the sale price of the property we will have to pay a broker when we sell the property.

The investment period is how long we will hold the property for before we sell it. Now that we have a good set of property assumptions down, we can begin to make calculations based on these assumptions.

A Note on Time Periods

There are many ways to begin forecasting out values across time. You could project financials monthly, quarterly, annually or some combination of the three. For most models, you should consider forecasting the financials monthly during the first couple years.

By doing so, you allow users of the model to see some of the cyclicality of the business (if there is any). It also allows you to spot certain problems with the business model that may not show up in annual projections (such as cash balance deficiencies). After the first couple of years, you can then forecast the financials on an annual basis.

For our purposes, annual projections will cut down on the complexity of the model. One side effect of this choice is that when we begin amortizing mortgages later, we will wind up incurring more interest expense than we would if we were making monthly principal payments (which is what happens in reality).

Another modeling choice you may want to consider is whether to use actual date headings for your projection columns (12/31/2010, 12/31/2011, …). Doing so can help with performing more complex function later, but again, for our purposes, we will simply use 1, 2, 3, etc. to measure out our years. In Excel, we can play with the formatting of these numbers a bit to read:

Year 1 Year 2 Year 3 Year 4 …

These numbers should be entered below our assumptions box with the first year starting in at least column B. We will carry these values out to year ten. Projections made beyond ten years do not have much credibility so most financial models do not exceed ten years.

On to the Projections

Now that we have set up our time labels on the “Property” worksheet, we are ready to begin our projections. Here are the initial values we want to project for the next ten years in our model:

Property Value
Annual Rent
Property Sale
Broker Fee
Mortgage Bal.
Equity Line Bal.
Net Proceeds
Owned Property Value

Add these line items in column A just below and to the left of where we added the year labels.

The property value line will simply project the value of the property over time. The value in year one will be equal to our purchase price assumption and the formula for it will simply reference that assumption. The formula for each year to the right of the first year will be as follows:

=B14*(1+$B$7)

Where B14 is the cell directly to the left of the year in which we are currently calculating the property value and $B$7 is an absolute reference to our “Annual Appreciation” assumption. This formula can be dragged across the row to calculate the remaining years for the property value.

The annual rent line will calculate the annual rental income from the property each year. The formula for the first year appears as follows:

=IF(B12>=$B$10,0,B5*12*$B$6)

B12 should be the “1” in the year labels we created. $B$10 should be an absolute reference to our investment period assumption (the data in our assumption cell should be an integer even if it is formatted to read “years,” otherwise the formula will not work). B5 should be a reference to our monthly rent assumption, and $B$6 should be an absolute reference to the occupancy rate.

What this function says is that if our investment period is less than the year in which this value is to be calculated, then the result must be zero (we will no longer own the property after it is sold, so we can’t collect rent). Otherwise, the formula will calculate the annual rent, which is the monthly rent multiplied by twelve and then multiplied by the occupancy rate.

For subsequent years, the formula will look similar to:

=IF(C12>=$B$10,0,B16*(1+$B$8))

Again, if the investment period is less than the year in which this value is to be calculated, then the result will be zero. Otherwise we simply take the value of last years rental income and increase it by our annual rent increase assumption in cell $B$8.

Time to Exit

Now that we have forecasted property values and rental income, we can now forecast the proceeds from the eventual sale of the property. In order to calculate the net proceeds from the sale of our property, we will need to forecast the values mentioned above: property sale price, broker fee, mortgage balance and equity line balance.

The formula for forecasting the sale price is as follows:

=IF(B12=$B$10,B14,0)

This formula states that if the current year (B12) is equal to our investment period ($B$10) then our sale price will be equal to our projected property value in that particular year (B14). Otherwise, if the year is not the year we’re planning to sell the property, then there is no sale and the sale price is zero.

The formula to calculate broker fees takes a similar approach:

=IF(B18=0,0,B18*$B$9)

This formula states that if the sale price for a particular year (B18) is equal to zero, then broker fees are zero. If there’s no sale, there’s no broker fees. If there is a sale then broker fees are equal to the sale price (B18) multiplied by our assumption for broker fees ($B$9).

Our mortgage balance and our equity line balance we will calculate on the next worksheet, so for now we will leave two blank lines as placeholders for these values. Our net proceeds from the property sale will simply be the sale price less broker fees less the mortgage balance, less the home equity line balance.

Let’s add one more line called “Owned Property Value.” This line will show the value of the property we own, so it will reflect a value of zero once we have sold it. The formula will simply be:

=IF(B12>=$B$10,0,B14)

B12 refers to the current year in our year label row. $B$10 refers to our investment period assumption, and B14 refers to the current years value in the property value line we calculated. All this line does is represent our property value line, but it will show zero for the property value after we sell the property.

On to the Financing

Now let’s model how we will finance the property acquisition. Let’s name a new tab “Financing” and add the title “Financing” at the top of the worksheet. The first thing we need to know is how much we need to finance.

To start, let’s type “Purchase Price” a few lines below the title. To the right of this cell make a reference to our purchase price assumption from the “Property” tab (=Property!B4). We will format the text of this cell to be green because we are linking to information on a different worksheet. Formatting text in green is a common financial modeling convention to help keep track of where information is flowing from.

Below this line, let’s type “Working Capital.” To the right of this cell, let’s enter an assumption of $5,000.00 (formatted in blue text to indicate an input). Our working capital assumption represents additional capital we think we’ll need in order to cover the day-to-day management of the investment property. We may have certain expenses that aren’t fully covered by our rental income and our working capital will help make sure we don’t run into cash flow problems.

Below the working capital line, let’s type “Total Capital Needed” and to the right of this cell sum the values of our purchase price and working capital assumption. This sum will be the total amount of capital we will need to raise.

Capital Sources

A couple lines below our “Total Capital Needed,” let’s create a capital sources box. This box will have six columns with the headings: source, amount, % purchase price, rate, term and annual payment. Two typical sources of capital for acquiring a property are a mortgage and an equity line of credit (or loan). Our final source of capital (for this model anyway) will be our own cash or equity.

In the sources column, let’s add “First Mortgage,” “Equity Line of Credit,” and “Equity” in the three cells below our sources heading. For a typical mortgage, a bank will usually lend up to 80% of the value of the property on a first mortgage, so let’s enter 80% in the line for the first mortgage under the % purchase price heading (again, formatted in blue to indicate an input value).

We can now calculate the amount of our first mortgage in the amount column with the following formula:

=B5*C11

B5 is a reference to our purchase price and C11 is a reference to our % purchase price assumption.

In the current market, banks are reluctant to offer equity lines of credit if there is less than 25% equity invested in the property, but let’s pretend that they are willing to lend a bit. Let’s assume that they will lend us another 5% of the property value in the form of an equity line. Enter 5% (in blue) in the equity line of credit line under the % purchase price heading.

We can use a similar formula to calculate the equity line amount in the amount column:

=B5*C12

Now that we have the amount of bank financing available for our purchase, we can calculate how much equity we will need. Under the amount heading in the row for equity, enter the following formula:

=B7-B11-B12

B7 is our total financing needed. B11 is the financing available from the first mortgage and B12 is the financing available from the equity line of credit. Again, we’re assuming that we’ll have to cough up the cash for anything we cannot finance through the bank.

The Cost of Capital

Now let’s figure out what this financing is going to cost us. For interests rates, let’s assume 5% on the first mortgage and 7% on the equity line. Enter both of these values in blue in our rate column. For terms, a typical mortgage is 30 years and an equity line might be 10 years. Let’s enter those values in blue under the term heading.

The annual payment column will be a calculation of the annual payment we will have to make to fully pay off each loan by the end of its term inclusive of interest. We will use an Excel function to do this:

=-PMT(D11,E11,B11,0)

The PMT function will give us the value of the fixed payment we will make given a certain rate (D11), a certain number of periods (E11), a present value (B11) and a future value (which we want to be zero in order to fully repay the loan). We can then use the same formula in the cell below to calculate the payment for the equity line.

Now we’re ready to map out our projections. Let’s start by copying column headings from the property tab (Year 1, Year 2, etc.) and paste them on the finance tab below our capital sources box. Let’s also pull the owned property value line from the property tab (marking the values in green to show that they come from a different sheet).

Now let’s forecast some balances related to our first mortgage. Let’s label this section of the worksheet “First Mortgage” and below it add the following line items in the first column:

Beginning Balance
Interest PMT
Principal PMT
Ending Balance

Post Sale Balance

For year one of our beginning balance, we will just reference our first mortgage amount (=B11). For years two and later, we will simply reference the previous years ending balance (=B25).

To calculate the interest payment for each year, we simply multiply the beginning balance by our assumed interest rate (=B22*$D$11). B22 would be the current year’s beginning balance and $D$11 would be our assumed interest rate.

To calculate each year’s principal payment, we simply subtract the current year’s interest payment from our annual payment (=$F$11-B23). $F$11 is the annual payment we calculated before, and B23 is the current year’s interest payment.

Our ending balance is simply our beginning balance minus our principal payment (=B22-B24).

Finally, our post sale balance is simply our ending balance for each year or zero if we have already sold the property (=IF(B19=0,0,B25)). This line will make it easy for us to represent our debt when we go to construct our balance sheet later on.

We now repeat the same lines and calculations for projecting our equity line of credit balances. Once we are done with these two sources, we have completed our financing worksheet.

Taking a Step Back

We can now drop in our mortgage and equity line balances back on the property tab in order to calculate our net proceeds. For the mortgage balance we use the formula:

=IF(B18=0,0,Financing!B22)

B18 refers to the current year’s property sale value. If the value is zero, then we want the mortgage balance to be zero, because we are not selling the property in that particular year and don’t need to show a mortgage balance. If the value is not zero, then we want to show the mortgage balance for that particular year which can be found on the financing tab (Financing!B22).

We use the same formula for calculating the equity line balance.

On to Expenses

Let’s label our expenses tab “Expenses” and add the same title to the top of the worksheet. This worksheet will be simple and straightforward. First, let’s create an assumptions table with the following input labels:

Tax Rate
Annual Home Repairs
Annual Rental Broker Fees
Other Expenses
Inflation

Next to each of these cells, let’s enter the following assumption values in blue:

1.10%
$800.00
$100.00
$50.00
1.50%

Each of these assumptions represents some component of the ongoing costs of managing a property. Below our assumptions box, let’s again paste our year headings from one of our other worksheets (Year 1, Year 2, etc.).

Let’s drop in a line that shows our owned property value that we calculated earlier and format these values in green. We will need these values in order to calculate our tax expense, so it’ll be easier to have it on the same worksheet.

Below this line, let’s add a few line items that we’ll be forecasting:

Home Repairs
Rental Broker Fees
Other Expenses

Taxes

Our first year of home repairs will simply be equal to our annual assumption (=B5). For subsequent years, though, we will need to check to see if we still own the property. If not, our cost will be zero. If so, we want to grow our home repairs expense by the inflation rate. Here’s what the function for subsequent years should look like:

=IF(C$13=0,0,B15*(1+$B$8))

In this case, C$13 is the current year’s property value, B15 is the previous year’s home repair expense, and $B$8 refers to the inflation rate. For rental broker fees and other expenses, we can use the same methodology to forecast these expenses.

For taxes, we will need to use a different calculation. Property taxes hinge on the value of the property, which is why we have used a percentage to represent the tax assumption. Our formula to calculate taxes will be as follows:

=B13*$B$4

Since our taxes will be zero when our property value is zero, we can simply multiply our property value (B13) by our assumed tax rate ($B$4). And now we have forecasted our expenses.

Putting It All Together

Now comes the fun part. We need to put all of our projections into presentable financial statements. Since this will be the part of the model that gets passed around, we’ll want to make it especially clean and well formatted.

Let’s label the tab “Financials” and enter the same title at the top of the worksheet. A couple lines below, we’ll start our balance sheet by adding a “Balance Sheet” label in the first column. Just below this line, we’ll drop in our standard year headings, only this time we want to include a Year 0 before the Year 1 column.

Along the left side of the worksheet just below the year headings, we’ll layout the balance sheet as follows:

Cash
Property

Total Assets

First Mortgage
Equity Line of Credit
Total Debt

Paid-In Capital
Retained Earnings
Total Equity

Total Liabilities & Equity

Check

Our cash value in year zero will be equal to the amount of equity we plan to invest, so we will reference our equity value from the finance worksheet (=Financing!B13) and format the value in green.

Property, first mortgage, equity line and retained earnings will all be zero in year zero because we haven’t invested anything yet. We can go ahead and add in the formulas for total assets (cash plus property), total debt (first mortgage plus equity line), total equity (paid-in capital plus retained earnings) and total liabilities and equity (total debt plus total equity). These formulas will remain the same for all years of the balance sheet.

For the year zero balance for paid-in capital, we’ll use the same formula as cash for year zero (=Financing!B13).

Returning to cash, we will use this line as our plug for the balance sheet since cash is the most liquid item on the balance sheet. To make cash a plug, we make cash equal to total liabilities and equity minus property. This should ensure that the balance sheet always balances. We still need to watch to see if our cash is ever negative, which could present a problem.

On a balance sheet, property is usually represented at its historical value (our purchase price), so we will use the following formula to show our property value and format it in green:

=IF(C5>=Property!$B$10,0,Property!$B$4)

C5 represents the current year. Property!$B$10 is a reference to our investment period assumption and $B$4 is a reference to the purchase price. The value of the property will be either zero (after we have sold it) or equal to our purchase price.

Our first mortgage and equity line balances we can simply pull from the post sale balance on the finance tab. We format each line in green to show that it is being pulled from another worksheet.

Paid-in capital, will be equal to either our original investment (since we won’t be making additional investments) or zero after we have sold the property. The formula is as follows:

=IF(C5>=Property!$B$10,0,$B$16)

C5 represents the current year. Property!$B$10 is a reference to our investment period assumption and $B$16 is a reference to the year zero value of our paid-in capital.

We will have to skip the retained earnings line until after we have projected our income statement as it hinges on net income.

The check line is a quick way of telling if your balance sheet is in balance. It is simply equal to total assets minus total liabilities and equity. If the value is not equal to zero, then you know there’s a problem. As an extra bell and whistle, You can use conditional formatting to highlight any problems.

Calculating the Bottom Line

Below the check line, let’s set up our income statement in the same way we set up our balance sheet — with an “Income Statement” label followed by our year column headings. We will layout our income statement as follows:

Rental Income
Proceeds from Sale
Total Revenue

Home Repairs
Rental Broker Fees
Other Expenses
Total Operating Expenses

Operating Income

Interest Expense
Taxes

Net Income

Rental income, proceeds from sale, home repairs, rental broker fees, other expenses and taxes can simply be pulled from the other worksheets where we have calculated them (and formatted in green of course). Interest expense is simply the sum of the interest payments for both the first mortgage and the equity line on the financing tab.

The other line items are simple calculations. Total revenue is the sum of rental income and proceeds from sale. Total operating expenses is the sum of home repairs, rental broker fees and other expenses. Operating income is total revenue minus total operating expenses. Net income is operating income minus interest expense and taxes.

Now that we have our net income figure, we can jump back up to our retained earnings line in our balance sheet to finish that up. The formula for retained earnings starting in the first year and going forward should be as follows:

=IF(C5>=Property!$B$10,0,B17+C43)

Again, the IF function looks at the current year (C5) and compares it to our investment period (Property!$B$10). If it is greater than or equal to the investment period, then we have closed our our investment and the value is zero. Otherwise, the formula for retained earnings is the previous year’s retained earnings balance (B17) plus the current year’s net income.

And Now for Cash Flow

To answer our original question of what our return on this particular investment is going to be, we need to project the cash flow to the investor. To do so, let’s create another section below the income statement called “Investment Cash Flow,” which also has our year column headings. We’ll also want to add the following lines:

Initial Investment
Net Income
Cash Flow

Our initial investment line will only have a value in the first year zero cell, and it will be equal to our paid in capital only negative (=-B16). Our initial cash flow is negative because we make the equity investment to finance the project.

The rest of our cash flow comes in the form of net income. Since we have the net proceeds from the sale of the property flowing through net income as well, we can simply set the net income line equal to net income from our income statement. To maximize our potential return, we will assume that net income is paid out each year rather than being retained (this could result in some negative cash balances, but for simplicity’s sake, we’ll make this assumption).

Cash flow is simply the sum of the initial investment and net income for each year. The result should be a negative cell followed by some negative or positive net income figures (depending on our model’s assumptions). Now we’re ready to calculate our return.

A couple lines below the cash flow line, we’ll label a line “IRR” or internal rate of return. The internal rate of return is basically the discount rate at which your future cash flow is equal to your initial cash outflow. In other words, it’s the discount rate that gives the project a present value of zero. The formula we will enter to the right of this label is as follows:

=IF(ISERROR(IRR(B51:L51)),"N/A",IRR(B51:L51))

We’re adding some fancy formatting to the formula to make sure that if the IRR function can’t calculate the return, it shows up as “N/A.” The basic function for IRR will simply reference our cash flow cells (B51:L51).

We can now play around with our model inputs to see if our assumptions and our project make sense. If you have data from a similar project, you may want to input those values to see if your model closely follows the actual results of the project. This test will help you determine if your model is working properly.

Remember, a model is only as good as the assumptions you put into it, so even with a detailed working model of a project, you will still need to invest a lot of time researching appropriate assumptions.

Final Touches

Take some time to format your model as best as possible. Set up each page so that it can print properly. Make sure that other users of the model can clearly follow it to see what you have done.

This is just one example of a financial model. Other models may be more simple or much more detailed. In order to be a great modeler, you have to practice. Good luck!